w3Admin.w3Config.form

subroutine w3Admin.w3Config.form( pools, messages)

***********************************************************************

* w3Admin.w3Config.form: Display the specified server pool entries

*

* Pools: the data to be displayed, one row per serverpool/web server

*        a1 = serverpool

*        a2 = host

*        a3 = minimum

*        a4 = maximum

*        a5 = maxfree

*        a6 = minfree

*        a7 = frequency

*        a8 = port

*        a9 = heartbeat

*

* messages: Any messages to display. Each attribute is it's own message

*

***********************************************************************

* [00] 18Sep00 jr Initial creation

*

Include wbp w3Include                   

Include bp w3Admin.Include

call w3HtmlInit(w3Admin.background, "")

subs     = ""

subs<-1> = "##TITLE##":@vm:"FlashCONNECT Server Pool Maintenance"

subs<-1> = "#HEADLINE#":@VM:"FlashCONNECT Server Pool Maintenance"

call w3HtmlHeader("",subs)

call w3HtmlInsertSection("w3Config", "", "head")

*   Insert messages

if messages # "" then

   call w3Admin.InsertErrors(messages)

end

call w3HtmlFormBeg(w3_NP, "w3Admin")

* Start data table

call w3htmlInsertSection("w3Config", "", "table.head")

* save serverpool/host as hidden variables so deletes can be done properly

rows = dcount(pools<1>, @vm)

ids  = ""

for i = 1 to rows

    ids<-1>  = pools<2, i>:"#":pools<1, i>     ;* pool/host

    subs     = ""

    subs<-1> = "#HOST#"       :@vm:pools<2, i>

    subs<-1> = "#POOL#"       :@vm:pools<1, i>

    subs<-1> = "#MIN#"        :@vm:pools<3, i>

    subs<-1> = "#MAX#"        :@vm:pools<4, i>

    subs<-1> = "#MINFREE#"    :@vm:pools<6, i>

    subs<-1> = "#MAXFREE#"    :@vm:pools<5, i>

    subs<-1> = "#PERIOD#"     :@vm:pools<7, i>

    subs<-1> = "#PORT#"       :@vm:pools<8, i>

    subs<-1> = "#HB#"         :@vm:pools<9, i>

    subs<-1> = "#ID#"         :@vm:pools<2,i>:"#":pools<1,i>

    subs<-1> = "#ROW#"        :@vm:i

    call w3HtmlInsertSection("w3Config", subs, "table.detail")

next i

subs = "#ROW#" :@vm: rows + 1

call w3HtmlInsertSection("w3Config", subs, "table.add")

convert @am to "~" in ids

subs=""

subs<-1>= "#IDS#":@vm:ids

call w3HtmlInsertSection("w3Config", subs, "table.end")

call w3HtmlFormEnd     

call w3HtmlInsertSection("w3Config", subs, "foot")

*  Get the path which got us here so we can set it in the template

Action = ""

call w3Action(Action, "")

subs   = "#ACTION#":@vm:Action

call w3HtmlFooter("",subs)

return